1 POKE50257,16:REMEBERGEBEN V3.0D
5 POKE55,0:POKE56,48:POKE45,190:POKE46,42:CLR
7 PRINTCHR$(14)CHR$(8):POKE650,128
10 FORI=1TO40:H$=H$+" ":NEXT
30 A$="[176]":FORI=1TO16:A$=A$+"[192]":NEXT:A$=A$+"[174]"
31 A$=A$+"[157][221]":FORI=1TO18:A$=A$+"[157]":NEXT
32 A$=A$+"[221][157]":A$=A$+"[173]":FORI=1TO16:A$=A$+"[192]":NEXT:A$=A$+"[189]"
33 RA$=A$
35 RL$=LEFT$(H$,18)+"[157] ":FORI=1TO18:RL$=RL$+"[157]":NEXT:RL$=RL$+" [157]"
36 RL$=RL$+LEFT$(H$,18)
40 NN=1:GOSUB7000:POKE788,52:GOSUB150:GOTO2000
100 VC=1:HC=35:GOSUB295:PRINT"S:   [157][157][157]";SN+1
129 GOSUB700:SYS9888+616
130 PRINT:RETURN
150 REM RESET SPEICHER
160 SYS2*4096+2*256+11*16+7+616:NS=0:SN=0:DN$="":FORI=0TO9:A$(I)="":NEXT
170 RETURN
200 PRINT"[147]";
215 PRINT"";:PRINTH$;:VC=1:HC=1:GOSUB295
220 PRINTUB$:HC=16:GOSUB295:IFNNTHENPRINTDN$;
225 PRINT:NN=1
230 FORI=0TO9:PRINT" "RIGHT$(STR$(I),1)" [146] "A$(I):PRINT:NEXT:PRINT""H$
245 HC=1:VC=23:GOSUB295:PRINT"";
250 FORI=1TONO:PRINT"";:PRINTLEFT$(W$(I),1);:PRINT"";:PRINTMID$(W$(I),2)" ";:NEXT
255 VC=25:HC=1:GOSUB295:PRINTLEFT$(H$,39);:POKE56295,NF:POKE2023,160:PRINT"[146]";:RETURN
295 POKE211,HC-1:POKE214,VC-1:SYS58640:RETURN
296 POKE646,FA:POKE53280,RF:POKE53281,HF:RETURN
300 GETA$:IFA$=""THEN300
320 FORI=1TOLEN(G$):IFA$=MID$(G$,I,1)THEN350
325 NEXT
326 IFA$>="0"ANDA$<="9"THENI=ASC(A$)-58:GOTO350
330 M$="EINGABEFEHLER":GOSUB400:GOTO300
350 SI=I+10:M$="":GOSUB400:RETURN
400 HC=1:VC=24:GOSUB295:PRINT"[146]";:PRINTH$;
420 HC=21-INT((LEN(M$))/2):VC=24:GOSUB295:PRINTM$;:RETURN
500 HC=CX:VC=CY:GOSUB295:PRINT"[146]"RA$:RETURN
550 HC=CX:VC=CY:GOSUB295:PRINTRL$:RETURN
600 GOSUB295:SYS2*4096+256+9*16+14+616
630 A$="":L=PEEK(512):IFL=0THENRETURN
640 FORI=513TO512+L:A$=A$+CHR$(PEEK(I)):NEXT:RETURN
700 POKE160+11,EN:HB=INT(SN/256):POKE177,HB:POKE176,SN-256*HB:RETURN
750 L=LEN(A$):POKE512,L:IFL=0THENRETURN
780 FORI=513TO512+L:POKEI,ASC(MID$(A$,I-512,1)):NEXTI:RETURN
800 GOSUB700:SYS2*4096+4*256+4*16+10+616:GOTO630
850 GOSUB700:GOSUB750:SYS2*4096+4*256+1*16+9+616:RETURN
870 SYS2*4096+4*256+5*16+14+616:RETURN
900 LF=0:M$="BITTE MIT '@' BESTAETIGEN!"
920 GOSUB400
930 GETA$:IFA$=""THEN930
940 LF=0:IFA$="@"THENLF=1
945 M$="":GOTO400
950 HC=1:VC=25:GOSUB295
960 PRINT"ANZAHL SAETZE:    [157][157][157][157]"NSTAB(28)"FREI:      [157][157][157][157][157][157]";
965 FR=PEEK(247)+PEEK(248)*256
970 FR=40960-FR
975 FR=(FR/26624)*100
976 PRINTINT(FR)"%";:RETURN
1000 UB$="DEFINITION DER BEGRIFFE":W$(1)="WAHLTAFEL":NO=1:NN=0:GOSUB200
1020 G$="W":GOSUB300:M$="":GOSUB400:IFSI=11THEN2000
1035 CX=4:CY=2+SI*2:GOSUB500:HC=5:VC=CY+1:GOSUB600:A$(SI)=A$:GOSUB550:GOSUB1020
2000 PRINT"[147]"H$"WAHLTAFEL":HC=16:VC=1:GOSUB295:PRINT"................"
2015 GOSUB295:PRINTDN$
2025 PRINT"DEFINITION"
2030 PRINT"EDITOR"
2040 PRINT"VERARBEITUNG"
2045 PRINT"[146]KOMPLETT LOESCHEN"
2050 PRINT""H$
2055 PRINT"[146]FESTLEGUNG DES DATEINAMENS"
2060 PRINT"LADEN EINER DATEI"
2070 PRINT"SICHERN EINER DATEI"
2080 PRINT"";:GOSUB255
2090 G$="DVELSFK":GOSUB300:M$="":LF=0:GOSUB400:IFSI<11THEN2000
2100 ONSI-10GOTO1000,5000,3000,4000,4500,2200,2300
2200 HC=16:VC=1:GOSUB600:FORI=LTO1STEP-1:IFMID$(A$,I,1)="."ORMID$(A$,I,1)=" "THENNEXT
2220 DN$=LEFT$(A$,I):GOTO2090
2300 GOSUB900:IFLF=0THEN2090
2305 VC=1:HC=16:GOSUB295:PRINT"................":GOSUB150:GOTO2090
3000 UB$="EDITOR":W$(1)="WAHLTAFEL":W$(2)="VOR":W$(3)="RUECK":NO=5
3017 W$(4)="LOESCHEN":W$(5)="NEUER SATZ":GOSUB200:LF=0:SN=0
3040 IFNS=0THEN3080
3042 GOSUB100
3080 GOSUB950
3085 M$="":IFNS=0THENM$="KEINE DATEN IM SPEICHER"
3090 GOSUB400
3100 G$="WVRLN":GOSUB300
3110 IFSI>10THEN3200
3115 IFNS=0THEN3040
3120 CX=22:CY=2+SI*2:GOSUB500:HC=23:VC=CY+1:GOSUB600:GOSUB550
3140 IFNS<=SNTHENGOSUB870
3150 B$=A$:EN=SI:GOSUB800:IFFR<1ANDLEN(B$)>LEN(A$)THEN3190
3160 A$=B$:GOSUB850:GOTO3040
3190 M$="SPEICHER BELEGT":GOSUB400:GOSUB200:GOTO3040
3200 ONSI-10GOTO2000,3300,3350,3400,3500
3300 IFSN>=NS-1THENM$="LETZTER SATZ":GOSUB400:GOTO3100
3310 SN=SN+1:GOTO3040
3350 IFSN=0THENM$="ERSTER SATZ":GOSUB400:GOTO3100
3360 SN=SN-1:GOTO3040
3400 IFNS=0THEN3080
3410 SYS2*4096+5*256+16+2+616:NS=NS-1:IFSN=NSTHENSN=SN-1
3430 GOTO3040
3500 IFFR<1THENM$="SPEICHER BELEGT!":GOSUB400:GOTO3040
3501 SN=NS:NS=NS+1:GOSUB870:GOTO3040
4000 GOSUB900:IFLF=0THEN2090
4003 IFDK=0THEN4100
4005 GOSUB10000:IFFTHEN2090
4010 OPEN15,8,15:D$=DN$+",S,R":OPEN1,8,2,D$
4030 INPUT#15,F,F$:IFFTHENM$="DISKETTENFEHLER: "+F$:LF=0:GOSUB400:GOTO4060
4032 GET#1,A$:IFA$<>CHR$(1)THENM$="FREMDDATEI!":GOSUB400:F=1:GOTO4060
4035 INPUT#1,NS:FORI=0TO9:INPUT#1,A$(I):NEXT:SYS9420+616
4060 CLOSE1:CLOSE15
4070 IFFTHEN2090
4080 GOTO3000
4100 PRINT"[147]":OPEN1,1,0,DN$:F=0:GOTO4032
4500 IFNS=0THENM$="NICHTS IM SPEICHER":GOSUB400:GOTO2090
4505 IFDN$=""THENM$="BITTE ERST DATEINAMEN DEFINIEREN !":GOSUB400:GOTO2090
4510 IFDK=0THEN4600
4513 GOSUB10000:IFFTHEN2090
4515 OPEN15,8,15:D$=DN$+",S,W"
4520 OPEN1,8,2,D$
4530 INPUT#15,F,F$:IFFTHEN4700
4535 PRINT#1,CHR$(1):PRINT#1,NS:FORI=0TO9:IFA$(I)=""THENA$(I)=" "
4545 PRINT#1,A$(I):NEXT:SYS2*4096+4*256+8*16+4+616
4560 CLOSE1:CLOSE15:IFDK=0THEN2000
4580 GOTO2090
4600 PRINT"[147]":OPEN1,1,1,DN$:GOTO4535
4700 IFF<>63THENM$="DISKETTENFEHLER "+F$:GOSUB400:GOTO4560
4705 M$="WENN FILE UEBERSCHREIBEN,DANN '@'!":GOSUB400
4710 GETA$:IFA$=""THEN4710
4713 M$="":GOSUB400
4715 IFA$<>"@"THEN4560
4720 D$="@:"+D$:CLOSE1:GOTO4520
5000 IFNS=0THENM$="KEINE DATEN IM SPEICHER":GOSUB400:LF=1:GOTO2090
5005 FORI=0TO9:F$(I)="":NEXT
5010 UB$="VERARBEITUNG"
5015 W$(1)="WAHLTAFEL":W$(2)="SUCHEN":W$(3)="ORDNEN":NO=3:NN=0:GOSUB200:GOSUB950
5030 G$="WSO":GOSUB300:M$="":GOSUB400
5040 IFSI>10THENONSI-10GOTO2000,5200,5100
5060 CX=22:CY=2+SI*2:GOSUB500:HC=23:VC=CY+1:GOSUB600:F$(SI)=A$:GOSUB550:GOTO5030
5100 FORI=0TO9:IFF$(I)<>"*"THENNEXT:M$="BITTE MIT '*' WAEHLEN!":GOSUB400:GOTO5030
5105 EK=I
5110 PF=0:M$="ICH ORDNE...":GOTO5500
5200 PF=1:M$="ICH SUCHE...":GOTO5500
5500 LF=0:GOSUB400:BA=3*4096:L=0:FORI=0TO9
5520 F$=F$(I):L=LEN(F$):POKEBA,L:IFL=0THEN5550
5540 FORJ=1TOL:POKEBA+J,ASC(MID$(F$,J,1)):NEXT
5550 BA=BA+L+1:NEXTI
5600 IFPFTHENSYS2*4096+5*256+8*16+15+616
5601 IFPF=0THENEN=EK:GOSUB700:SYS2*4096+7*256+4*16+8+616
5602 BA=3*4096+256
5610 AN=PEEK(BA)+PEEK(BA+1)*256
5620 IFAN=0THENM$="KEINE DATEN GEFUNDEN":GOSUB400:GOTO5030
5700 UB$="DATENAUSGABE"
5710 W$(1)="WAHLTAFEL":W$(2)="VOR":W$(3)="RUECK":W$(4)="DRUCKEN"
5720 W$(5)="NEUE DATEI":NO=4+PF:GOSUB200
5730 M$="ORDNET":IFPFTHENM$="FUNDEN"
5731 M$=STR$(AN)+" SAETZE GE"+M$:GOSUB400
5740 PO=BA+2:PN=1
5750 SN=PEEK(PO)+PEEK(PO+1)*256:GOSUB100:GOSUB6200
5800 G$="WVRD":IFPFTHENG$=G$+"N"
5801 GOSUB300:M$="":GOSUB400
5805 IFSI<11THEN5800
5810 ONSI-10GOTO2000,5820,5850,5900,6000
5820 IFPN=ANTHENM$="LETZTER SATZ":GOSUB400:GOTO5800
5825 PN=PN+1:PO=PO+2:GOTO5750
5850 IFPN=1THENM$="ERSTER SATZ":GOSUB400:GOTO5800
5860 PN=PN-1:PO=PO-2:GOTO5750
5900 OPEN1,4,1:SYS2*4096+7*256+2*16+14+616
5901 IFPEEK(832)THENM$="KEIN DRUCKER ANGESCHLOSSEN !":LF=0:GOSUB400:CLOSE1:GOTO5800
5902 CLOSE1:GOTO6100
5910 OPEN4,4,(PEEK(53272)AND2)*3.5:IFEFTHEN5930
5920 PRINT#4,"DATEINAME    : ";DN$
5925 PRINT#4,"DATENSAETZE  :";NS
5927 PRINT#4,"AUSGESUCHT   :";AN
5929 PRINT#4,"----------------------------------------":PRINT#4
5930 PO=BA+2:FORPI=0TOAN-1
5940 SN=PEEK(PO)+PEEK(PO+1)*256
5943 IFEF=0THENPRINT#4,"DATENSATZ NR.:"SN
5944 PRINT#4:FOREN=0TOED:IFA$(EN)=""THEN5950
5945 IFEF=0THENPRINT#4,"  "A$(EN)":"LEFT$(H$,20-LEN(A$(EN)));
5948 GOSUB800:PRINT#4,A$
5950 NEXT:PO=PO+2:PRINT#4:NEXT:CLOSE4
5990 GOTO5010
6000 GOSUB900:IFLF=0THEN5800
6010 LF=0:M$="ICH ORDNE...":GOSUB400
6020 NS=AN:SYS2*4096+5*256+13*16+7+616
6030 GOTO2000
6100 VC=23:HC=1:GOSUB295
6105 PRINT"WAHLTAFEL DRUCKEN: ALLES NUR DATEN 0-9"
6110 G$="WA":GOSUB300
6120 IFSI<10THENED=SI:EF=1:GOTO5910
6130 IFSI=11THEN2000
6135 ED=9:EF=0:GOTO5910
6200 PRINT"ANZAHL SAETZE:    [157][157][157][157]"NSTAB(22)"LAUFENDE NR.:    [157][157][157][157]";PN;:RETURN
7000 PRINT"[147]";
7010 RF=0:HF=0:NF=5:SF=1:FA=NF:GOSUB296
7020 PRINT"    DDDD    A   TTTTT EEEEE  III
7030 [153]"    D   D  A A    T   E       I
7035 PRINT"    D   D A   A   T   E       I
7040 [153]"    D   D A   A   T   EEEE    I   ---
7045 PRINT"    D   D AAAAA   T   E       I
7050 [153]"    D   D A   A   T   E       I
7055 PRINT"    DDDD  A   A   T   EEEEE  III
7056 [153]:[153]
7060 [153]"  K   K   A    SSSS TTTTT EEEEE N   N
7065 PRINT"  K  K   A A  S       T   E     N   N
7070 [153]"  K K   A   A S       T   E     NN  N
7074 PRINT"  KK    A   A  SSS    T   EEEE  N N N
7080 [153]"  K K   AAAAA     S   T   E     N  NN
7085 PRINT"  K  K  A   A     S   T   E     N   N
7090 [153]"  K   K A   A SSSS    T   EEEEE N   N
7095 PRINT:PRINT:PRINT"             VON PETER SAGER"
7100 PRINT:PRINT:PRINT"ARBEITEN SIE MIT KASSETTE ODER DISKETTE?";
7110 G$="KD":GOSUB300
7120 IFSI<11THEN7110
7130 DK=0:IFSI=12THENDK=1
7999 RETURN
10000 OPEN1,8,1:SYS2*4096+7*256+2*16+14+616
10001 F=0:IFPEEK(832)THENF=1:M$="DISKETTENLAUFWERK FEHLT !":GOSUB400
10002 CLOSE1:RETURN